**Macro**

directory = getDirectory("Choose a Directory "); // prompts for directory with the images

list = getFileList(directory);

// for-loop below processes the files in the specified folder and outputs the quantification results in a table that can be copy/pasted into Excel

for (i=0; i<list.length; i++) {

path = directory+list[i];

showProgress(i, list.length);

// "run(...)" command below opens complex images, such as ones generated by AxioVision; use just "open(path)" for simple images

run("Bio-Formats Importer", "open=path autoscale color\_mode=Default view=Hyperstack stack\_order=XYCZT");

if (nImages>=1) {

imagename = list[i];

run("Split Channels"); // splits a multi-channel image into indiviual images fro processing and assigns channels numbers, such as C1, C2

selectImage("C2-"+imagename); // assume C2 is the nucleus-stain image

close(); // close nucleus-stain image, as only interested in quantifying f-actin

selectImage("C1-"+imagename); // assume C1 is the f-actin stain image

run("8-bit"); // image is converted to 8-bit for compatiblity with some of the following functions

run("Median...", "radius=2"); // smooths the image, making thresholded areas more uniform

run("Subtract Background...", "rolling=5000 sliding"); // subtracts background fluorescence, hue, etc; set rolling ball radius to optimize the amount of background removed

setThreshold(20, 255); // the thresholed values should be set by the user to produce the most accurate segmented mask image for quantification

run("Convert to Mask"); // creates the binary black-white image based on the threshold values defined above

//run("Watershed"); // watershed algorithm can be used to separate multiple cells that appear to be merged into one large particle

// command below sets quantification categories: area, standard deviation, and percent coverage of cell body

run("Set Measurements...", "area standard area\_fraction redirect=None decimal=2");

// command below extract the categories defined above for the thresholded particles; adjust particle size accordingly - for example set particle size to 50-400 um2 for detached dead cells and 500 - 7000 um3 for adherent cells

run("Analyze Particles...", "size=100-inf circularity=0.00-1.00 show=Nothing display summarize");

selectImage("C1-"+imagename);

close();

} else

print("Error opening "+path); // outputs an error if the specific folder of images cannot be opened

}

**Representative output**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| Slice | Count | Total Area | Average Size | Area Fraction |
| C1-250C-1-0127.zvi | 54 | 83278.79 | 1542.2 | 14.8 |
| C1-250C-1-0128.zvi | 35 | 186495.06 | 5328.43 | 33.1 |
| C1-250C-1-0129.zvi | 41 | 118677.45 | 2894.57 | 21.1 |
| C1-250C-1-0130.zvi | 50 | 65176.83 | 1303.54 | 11.6 |